ClassificationSieving Task

This task removes isolated classified pixels using blob grouping. Low pass or other types of filtering could be used to remove these areas, but the class information would be contaminated by adjacent class codes. The sieve classes method looks at the neighboring four or eight pixels to determine if a pixel is grouped with pixels of the same class. If the number of pixels in a class that are grouped is less than the value that you enter, those pixels will be removed from the class. When pixels are removed from a class using sieving, black pixels (unclassified) will be left. Use the ClassificationClumping task to remove the black pixels.

Example

The following example performs an unsupervised classification, followed by a sieving, then clumping operation to remove the remaining black pixels.

; Start the application

e = ENVI()

; Open an input file

File = Filepath('qb_boulder_msi', Subdir=['data'], $

Root_Dir=e.Root_Dir)

Raster = e.OpenRaster(File)

; Create a classification ENVIRaster

ClassTask = ENVITask('ISODATAClassification')

ClassTask.INPUT_RASTER = Raster

ClassTask.Execute

; Get the collection of data objects currently available in the Data Manager

DataColl = e.Data

; Add the class image to the Data Manager

DataColl.Add, ClassTask.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(ClassTask.OUTPUT_RASTER)

; Run the sieving task

SievingTask = ENVITask('ClassificationSieving')

SievingTask.INPUT_RASTER = ClassTask.OUTPUT_RASTER

SievingTask.Execute

; Run the clumping task

ClumpingTask = ENVITask('ClassificationClumping')

ClumpingTask.INPUT_RASTER = SievingTask.OUTPUT_RASTER

ClumpingTask.Execute

; Add the output to the Data Manager

DataColl.Add, ClumpingTask.OUTPUT_RASTER

; Display the result

Layer2 = View.CreateLayer(ClumpingTask.OUTPUT_RASTER)

; Flicker between the original classification and the result

; after clumping

Portal = View.CreatePortal()

Portal.Animate, 2.0, /FLICKER

Syntax

Result = ENVITask('ClassificationSieving')

Input parameters (Set, Get): CLASS_ORDER, INPUT_RASTER, MINIMUM_SIZE, OUTPUT_RASTER_URI, PIXEL_CONNECTIVITY

Output parameters (Get only): OUTPUT_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

CLASS_ORDER (optional)

Specify the order of class names in which sieving is applied to the classification image. If you do not specify this parameter, the classes are processed from first to last.

INPUT_RASTER (required)

Specify a raster on which to perform classification clumping.

MINIMUM_SIZE (optional)

Specify the minimum size of a blob (in pixels) to keep. The default value is two pixels.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER.

If you do not specify this parameter, or set it to an exclamation symbol (!), ENVI creates a temporary file.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.

PIXEL_CONNECTIVITY (optional)

Specify a value of 4 (four-neighbor) or 8 (eight-neighbor) indicating the regions around a pixel that are searched, for continuous blobs. The default is 8.