ClassificationSmoothing Task

This task removes speckling noise from a classification image. It uses majority analysis to change spurious pixels within a large single class to that class.

Example

The following example performs an unsupervised classification, followed by a smoothing operation.

; Start the application

e = ENVI()

; Open an input file

File = Filepath('qb_boulder_msi', Subdir=['data'], $

Root_Dir=e.Root_Dir)

Raster = e.OpenRaster(File)

; Create a classification ENVIRaster

ClassTask = ENVITask('ISODATAClassification')

ClassTask.INPUT_RASTER = Raster

ClassTask.Execute

; Get the collection of data objects currently available in the Data Manager

DataColl = e.Data

; Add the class image to the Data Manager

DataColl.Add, ClassTask.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(ClassTask.OUTPUT_RASTER)

; Run the smoothing task

SmoothTask = ENVITask('ClassificationSmoothing')

SmoothTask.INPUT_RASTER = ClassTask.OUTPUT_RASTER

SmoothTask.Execute

; Add the output to the Data Manager

DataColl.Add, SmoothTask.OUTPUT_RASTER

; Display the result

Layer2 = View.CreateLayer(SmoothTask.OUTPUT_RASTER)

; Flicker between the original classification and the classification after

; aggregation

Portal = View.CreatePortal()

Portal.Animate, 2.0, /FLICKER

Syntax

Result = ENVITask('ClassificationSmoothing')

Input parameters (Set, Get): INPUT_RASTER, KERNEL_SIZE, OUTPUT_RASTER_URI

Output parameters (Get only): OUTPUT_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

INPUT_RASTER (required)

Specify a classification raster on which to perform aggregation.

KERNEL_SIZE (optional)

Specify an odd number with the smoothing kernel size. The minimum value is 3 pixels, and the default value is 3 pixels.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER.

If you do not specify this parameter, or set it to an exclamation symbol (!), ENVI creates a temporary file.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.