OrthogonalSubspaceProjection Task

This task performs the Orthogonal Subspace Projection (OSP) target analysis.

Example

This example performs the following steps:

Opens an AVIRIS hyperspectral image subset.
Runs a forward minimum noise transform (MNF) to reduce noise in the data.
Defines three regions of interest (ROIs), each containing nine pixels of a common material.
Retrieves the spectra from the ROIs and uses their means as targets for Orthogonal Subspace Projection.
Runs the OSP task, which performs orthogonal subspace projection target analysis.
Displays the result. To see all of the bands, open the Data Manager.

; Start the application

e = ENVI()

; Open an input file

File = Filepath('AVIRISReflectanceSubset.dat', $

SUBDIR=['data', 'hyperspectral'], $

ROOT_DIR=e.Root_Dir)

Raster = e.OpenRaster(File)

; First run a Forward MNF on the data

Task = ENVITask('ForwardMNFTransform')

Task.INPUT_RASTER = Raster

Task.Execute

; Use the first 25 MNF bands to run OSP

Subset = ENVISubsetRaster(Task.OUTPUT_RASTER, BANDS=LINDGEN(25))

; Define three ROIs, each containing 9 pixels of a common material.

nSpectra = 9d

roi1 = ENVIROI(NAME='Green Field')

pixelAddr1 = [[77,182],[78,182],[79,182], $

[77,183],[78,183],[79,183], $

[77,184],[78,184],[79,184]]

roi1.AddPixels, pixelAddr1, SPATIALREF=Subset.SPATIALREF

roi2 = ENVIROI(NAME='Soil')

pixelAddr2 = [[386,285],[387,285],[388,285], $

[386,286],[387,286],[388,286], $

[386,287],[387,287],[388,287]]

roi2.AddPixels, pixelAddr2, SPATIALREF=Subset.SPATIALREF

roi3 = ENVIROI(NAME='Ground')

pixelAddr3 = [[296,326],[297,326],[298,326], $

[296,327],[297,327],[298,327], $

[296,328],[297,328],[298,328]]

roi3.AddPixels, pixelAddr3, SPATIALREF=Subset.SPATIALREF

; Retrieve the spectra from the ROIs and use their mean as targets

; for the Orthogonal Subspace Projection (OSP) task

spectra1 = Subset.GetData(ROI=roi1)

mean1 = Total(spectra1,1) / nSpectra

spectra2 = Subset.Getdata(ROI=roi2)

mean2 = Total(spectra2,1) / nSpectra

spectra3 = Subset.GetData(ROI=roi3)

mean3 = Total(spectra3,1) / nSpectra

targets = [[mean1],[mean2],[mean3]]

; Get the task from the catalog of ENVITasks

Task = ENVITask('OrthogonalSubspaceProjection')

Task.INPUT_RASTER = Subset

Task.TARGET = targets

; Run the task

Task.Execute

; Get the data collection

dataColl = e.Data

; Add the output to the data collection

dataColl.Add, Task.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(Task.OUTPUT_RASTER)

Syntax

Result = ENVITask('OrthogonalSubspaceProjection')

Input properties (Set, Get):BACKGROUND, INPUT_RASTER, OUTPUT_RASTER_URI, TARGET

Output properties (Get only):OUTPUT_RASTER

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods

This task inherits the following methods from ENVITask:

Properties

This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

BACKGROUND (optional)

Specify the background spectra. It is a floating-point array. The array size is [number of bands, number of background spectra]. If not defined, at least two target spectra are needed.

INPUT_RASTER (required)

Specify an input raster to process.

OUTPUT_RASTER

This is a reference to the output raster of filetype ENVI.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path to export the associated OUTPUT_RASTER.

If you set this property to an asterisk symbol (*), the output raster will be virtual and not written to disk.
If you do not specify this property, or set it to an exclamation symbol (!), a temporary file will be created.

TARGET (required)

Specify the target spectra. It is a floating-point array. The array size is [number of bands, number of target spectra].

Version History

ENVI 6.0

Introduced

API Version

4.2