AgCalculateGetisOrd Task

This task creates a Z-score raster to find regions that are statistically significant.

ENVI calculates Getis-Ord Gi* local statistics (Getis and Ord, 1992) to group neighboring pixels of similar value into clusters. The algorithm evaluates each pixel and its surrounding pixels within a specified distance to classify the pixel as "hot" or "cold" (statistically significant clusters of high or low values, respectively) or neutral (not statistically significant). Hotspot analysis can be used to look for variations in crop health.

This task requires a separate license for the ENVI Crop Science Module; contact your sales representative for more information.

Example

This example creates a Z-score raster from a spectral index image of alfalfa fields.

The source image consists of layer-stacked Sentinel-2A visible, near-infrared, and shortwave-infrared bands with a spatial resolution of 10 meters. The image is from eastern Idaho, USA. The accompanying region of interest (ROI) file encompasses alfalfa fields. It is used to mask out all non-alfalfa pixels from the source image. The masked raster is then used to create a Modified Simple Ratio index, which is used as input to AgCalculateGetisOrd Task.

; Start the application

e = ENVI()

; Open an input file

File = Filepath('CircularFields_Sentinel2A.dat', $

Subdir=['data', 'crop_science'], $

Root_Dir=e.Root_Dir)

Raster = e.OpenRaster(File)

; Only process the actively growing fields

; using an ROI mask

ROIFile = Filepath('CircularFields_AlfalfaROI.xml', $

Subdir=['data', 'crop_science'], $

Root_Dir=e.Root_Dir)

ROI = e.OpenROI(ROIFile)

maskedRaster = ENVIROIMaskRaster(Raster, ROI)

; Create a Modified Simple Ratio index

MSRImage = ENVISpectralIndexRaster(maskedRaster, 'MSR')

; Get the task from the catalog of ENVITasks

Task = ENVITask('AgCalculateGetisOrd')

; Define the task inputs

Task.INPUT_RASTER = MSRImage

Task.DISTANCE = 10 ; meters

; Run the task

Task.Execute

; Get the collection of data objects currently

; available in the Data Manager

DataColl = e.Data

; Add the output to the Data Manager

DataColl.Add, Task.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(Task.OUTPUT_RASTER)

Layer.QUICK_STRETCH = 'Equalization'

Syntax

Result = ENVITask('AgCalculateGetisOrd')

Input parameters (Set, Get): DISTANCE, INPUT_RASTER, OUTPUT_RASTER_URI

Output parameters (Get only): OUTPUT_RASTER

Input Parameters

DISTANCE (required)

Specify the radius of the area around each pixel used to calculate the local mean. If the input raster has a valid spatial reference, then the radius is measured in meters. Otherwise, it is measured in pixels.

INPUT_RASTER (required)

Specify a single-band input raster.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER.

If you do not specify this parameter, or set it to an exclamation symbol (!), ENVI creates a temporary file.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.