ENVIGridDefinition::ConvertMapToGrid

This function method returns the closest (row, column) index for a given map coordinate.

Example

; Start the application

e = ENVI(/HEADLESS)

 

; Select input data

file = FILEPATH('qb_boulder_msi', ROOT_DIR=e.ROOT_DIR, $

  SUBDIRECTORY = ['data'])

raster = e.OpenRaster(file)

 

; Retrieve the grid parameters of the raster

PixelSize = raster.SPATIALREF.PIXEL_SIZE

CoordSysString = raster.SPATIALREF.COORD_SYS_STR

NumRows = raster.NROWS

NumCols = raster.NCOLUMNS

TiePointMap = raster.SPATIALREF.TIE_POINT_MAP

TiePointPixel = raster.SPATIALREF.TIE_POINT_PIXEL

CoordSys = ENVICoordSys(COORD_SYS_STR=CoordSysString)

 

; Create a grid definition for the original raster

Grid = ENVIGridDefinition(CoordSys, $

  PIXEL_SIZE=PixelSize, $

  NROWS=NumRows, $

  NCOLUMNS=NumCols, $

  TIE_POINT_MAP=TiePointMap, $

  TIE_POINT_PIXEL=TiePointPixel)

 

; Get the pixel location for a set of map coordinates

Grid.ConvertMapToGrid, 480600.4D, 4428841.2D, x, y

PRINT, x, y

IDL prints:

119.00000 49.000000

Syntax

ENVIGridDefinition.ConvertMapToGrid, X, Y, Column, Row

Arguments

X

Specify the easting or longitude value.

Y

Specify the northing or latitude value.

Column

A named variable containing the zero-based column number.

Row

A named variable containing the zero-based row number.

Keywords

Keywords are applied only during the initial creation of the object.

ERROR

Set this keyword to a named variable that will contain any error message issued during execution of this routine. If no error occurs, the ERROR variable will be set to a null string (''). If an error occurs and the routine is a function, then the function result will be undefined.

When this keyword is not set and an error occurs, ENVI returns to the caller and execution halts. In this case, the error message is contained within !ERROR_STATE and can be caught using IDL's CATCH routine. See IDL Help for more information on !ERROR_STATE and CATCH.

See Manage Errors for more information on error handling in ENVI programming.

Version History

ENVI 5.2

Introduced

API Version

4.2

See Also

ENVIGridDefinition, ENVICoordSys